void setup() 
{
    Serial.begin(9600);
}

void loop() 
{
    Serial.write("Hallo\n");
    delay(500);
}

Code 0-1: erstes Beispiel zur seriellen Schnittstelle

class LED 
{

private:
  int pin;
  int PDX;

public:
  LED(int num) 
  {

    pin = num;

    if (num == 1) {
      PDX = PD7;
    }
    if (num == 2) {
      PDX = PD4;
    }
    if (num == 3) {
      PDX = PD0;
    }
    if (num == 4) {
      PDX = PD1;
    }

    DDRD |= (1 << PDX);
  };

  void on() 
  {
    PORTD |= (1 << PDX);
  }

  void off() 
  {
    PORTD &= ~(1 << PDX);
  }
};

LED john(1);   // (Pin 6)
LED steven(2); // (Pin 4)
LED ryan(3);  // (Pin 3)
LED chris(4);  // (Pin 2)

void setup() 
{

}

void loop() 
{
  
  john.on();
  delay(200);
  steven.on();
  delay(200);
  ryan.on();
  delay(200);
  chris.on();
  delay(200);

  john.off();
  steven.off();
  ryan.off();
  chris.off();
  delay(200);
}

Code 0-2: Studentische Lösung.

Katoden (-):
A - PB0
B - PB1
C - PB2
D - PB3
E - PB4
F - PB6
G - PB7

PB5 : SERVO

Anoden (+):
Ditit1 - DIO 2
Ditit2 - DIO 3
Ditit3 - DIO 4

Code 0-3: Ditit4 - DIO 5

void setup() 
{
       ICR1 = 62500-1; // Siehe Datenblatt Seite 123
       TCNT1=0; //Zählregister von Timer 1
       // WGM13...WGM10 = 1100 => Mode 12 == CTC, mit ICR1 als TOP, siehe Datenblatt zu Atmega32u4, Seite 133.
       // CS12..CS10 = 100 => Vorteilung 256 => Zählen läuft mit 62500Hz, Seite 134.
       // COM1A1,COM1A0 = 00, COM1B1,COM1B0 = 00 => "normal Port-Operation" (Keine Signale herausschicken), Seite 132.
       TCCR1A = (0<<COM1A1) | (0<<COM1A0) | (0<<COM1B1) | (0<<COM1B0) | (0<<COM1C1) | (0<<COM1C0) | (0<<WGM11) | (0<<WGM10);
       TCCR1B = (0<<ICNC1) | (0<<ICES1) | (1<<WGM13) | (1<<WGM12) | (1<<CS12) | (0<<CS11) | (0<<CS10); 

       // PB7 == DIO 11, vergl. kramann.info LED-Leiste
       DDRB |= (1<<PB7);
       PORTB &= ~(1<<PB7); //LED aus
}

// 1Hz Blinken
void loop() 
{
    if(TCNT1<31250) //Bei der unteren Hälfte des Zählvorgangs aus.
        PORTB &= ~(1<<PB7); //LED aus
    else    
        PORTB |= (1<<PB7); //LED an
}

Code 0-4: 1 Hz Blinken über CTC-Mode des Zählers 1. Zählstand wird ständig geprüft.

void setup() 
{
       ICR1 = 62500/2-1; // Siehe Datenblatt Seite 123
       TCNT1=0; //Zählregister von Timer 1
       // WGM13...WGM10 = 1100 => Mode 12 == CTC, mit ICR1 als TOP, siehe Datenblatt zu Atmega32u4, Seite 133.
       // CS12..CS10 = 100 => Vorteilung 256 => Zählen läuft mit 62500Hz, Seite 134.
       // COM1A1,COM1A0 = 01, COM1B1,COM1B0 = 01 => "Toggle OCnA/OCnB/OCnC on compare match", Seite 131.
       // Frequenz, siehe: S.123.
       TCCR1A = (0<<COM1A1) | (1<<COM1A0) | (0<<COM1B1) | (1<<COM1B0) | (0<<COM1C1) | (1<<COM1C0) | (0<<WGM11) | (0<<WGM10);
       TCCR1B = (0<<ICNC1) | (0<<ICES1) | (1<<WGM13) | (1<<WGM12) | (1<<CS12) | (0<<CS11) | (0<<CS10); 

       // OCR1A ist auf Digital Pin 9 == PB5, vergl. kramann.info, Arduino.
       // OCR1B ist auf Digital Pin 10 == PB6, vergl. kramann.info, Arduino.
       DDRB |= (1<<PB5) | (1<<PB6);
       //pinMode(9,OUTPUT);  
       //pinMode(10,OUTPUT);  
}

void loop() 
{
}

Code 0-5: 1Hz über fest konfiguriertes Toggeln auf Pin9 und 10, kein Code in loop() nötig!

             RXD____  ____TXD
Arduino 1           \/        Arduino 2
                    /\
             TXD----  ----TXD

             GND----------GND

Code 0-6: Verbindung zweier Arduino über Kreuz.

void setup() 
{
    Serial.begin(9600);
    Serial1.begin(9600);
}

void loop() 
{
    if(Serial.available())
    {
        char c = Serial.read();
        Serial1.write(c);
    }
    if(Serial1.available())
    {
        char antwort = Serial1.read();
        Serial.print("Antwort: ");
        Serial.write(antwort);
        Serial.println();
    }
}

Code 0-7: Sertest1 für Arduino ttyACM0, wo später der serielle Monitor geöffnet wird.

void setup() 
{
    Serial1.begin(9600);
}

void loop() 
{
    if(Serial1.available())
    {
        char c = Serial1.read();
        Serial1.write(c+1);
    }
}

Code 0-8: Sertest2 für Arduino ttyACM1

#include<avr/io.h>
#define TAKTFREQUENZ 16000000
#define BAUDRATE 9600

void setup() 
{
    //Serial1.begin(9600);
    
    //Merken des in UBRR zu speichernden Wertes.
    //Examples of Baud Rate Setting, Seite 206
    //Seite 191 Datenblatt
    //Seite 213 Datenblatt
//    unsigned int baudregister = (TAKTFREQUENZ/(16*BAUDRATE))-1; 
    unsigned int baudregister = (1000000/BAUDRATE)-1; 

    //setzen der Baudrate
    //UBRRH1 = (unsigned char) (baudregister>>8); //Setzen des HIGH-Bytes des Baudraten-Registers
    //UBRRL1 = (unsigned char)  baudregister;     //Setzen des LOW -Bytes des Baudraten-Registers
    UBRR1 = baudregister;
    //Einschalten des Senders und des Empfängers
    //Seite 190 Datenblatt
    UCSR1B = (1<<TXEN1) | (1<<RXEN1) | (0<<UCSZ12);  

    //Setzen des Nachrichtenformats: 8 Datenbits, 1 Stopbits
    //  USBS1 == 0 == 1 stop bit
    //  UCSZ12 UCSZ11 UCSZ10 == 0 1 1 == 8 Datenbit
    //Seite 212 Datenblatt
    UCSR1C = (1<<UCSZ11) |  (1<<UCSZ10) |  (0<<USBS1);
}

void loop() 
{
    while( !(UCSR1A & (1<<RXC1)) ) DDRB|=0;  //Warten bis der Uebertragungspuffer ein Zeichen empfangen hat
  
    int c = UDR1;
    //Serial1.write(c+1);
    while( !(UCSR1A & (1<<UDRE1)) ) DDRB|=0; //Warten bis der Uebertragungspuffer leer ist
    UDR1 = c+1;
}

Code 0-9: Sertest2reg

MPU6050 ---- Arduino

VCC     ---- 3.3V
GND     ---- GND
SCL     ---- SCL
SDA     ---- SDA

Code 0-10: Verbindung MPU6050 mit Arduino

#include<math.h>
#include<Wire.h>
const int MPU=0x68;  // I2C address of the MPU-6050
int16_t AcX=0,AcY=0,AcZ=0,Tmp=0,GyX=0,GyY=0,GyZ=0;
double TEMPERATUR = 0.0;
void setup() 
{
  Serial.begin(9600);
  Wire.begin();
  Wire.beginTransmission(MPU);
  Wire.write(0x6B);  // PWR_MGMT_1 register
  Wire.write(0);     // set to zero (wakes up the MPU-6050)
  Wire.endTransmission(true);
  delay(500);
}

void loop() 
{
  Wire.beginTransmission(MPU);
  Wire.write(0x3B);  // starting with register 0x3B (ACCEL_XOUT_H)
  Wire.endTransmission(false);
  Wire.requestFrom(MPU,14,true);  // request a total of 14 registers
  AcX=Wire.read()<<8|Wire.read();  // 0x3B (ACCEL_XOUT_H) & 0x3C (ACCEL_XOUT_L)     
  AcY=Wire.read()<<8|Wire.read();  // 0x3D (ACCEL_YOUT_H) & 0x3E (ACCEL_YOUT_L)
  AcZ=Wire.read()<<8|Wire.read();  // 0x3F (ACCEL_ZOUT_H) & 0x40 (ACCEL_ZOUT_L)
  Tmp=Wire.read()<<8|Wire.read();  // 0x41 (TEMP_OUT_H) & 0x42 (TEMP_OUT_L)
  GyX=Wire.read()<<8|Wire.read();  // 0x43 (GYRO_XOUT_H) & 0x44 (GYRO_XOUT_L)
  GyY=Wire.read()<<8|Wire.read();  // 0x45 (GYRO_YOUT_H) & 0x46 (GYRO_YOUT_L)
  GyZ=Wire.read()<<8|Wire.read();  // 0x47 (GYRO_ZOUT_H) & 0x48 (GYRO_ZOUT_L)

  TEMPERATUR = Tmp/340.00+36.53;
  
  Serial.print("AcX = "); Serial.print(AcX);
  Serial.print(" | AcY = "); Serial.print(AcY);
  Serial.print(" | AcZ = "); Serial.print(AcZ);
  Serial.print(" | Tmp = "); Serial.print(TEMPERATUR);  //equation for temperature in degrees C from datasheet
  Serial.print(" | GyX = "); Serial.print(GyX);
  Serial.print(" | GyY = "); Serial.print(GyY);
  Serial.print(" | GyZ = "); Serial.print(GyZ);
  
  delay(500);
}

Code 0-11: Testprogramm, um alle Sensordaten, die der MPU6050 liefert im Serial Monitor ansehen zu können.