//Laden einer Datei in ein Array, das die Zeilen der Datei dann enthält:
String[] werte = loadStrings("meinedatei.txt");

//Umwandeln eines Strings in eine Zahl:
double zahl = Double.parseDouble("56.5");
int z = (int)Double.parseDouble("56.5");

Code 0-1: Hinweise

if (cam!=null && cam.isStarted()) 
{
    cam.read();
    cam.updatePixels();
    cam.loadPixels();
    int[] newpix = cam.pixels;
    if(newpix!=null)
       for(int i=0;i<newpix.length;i++)
        pix[i] = newpix[i];
...
}

Code 0-2: pixels aus Kamerabild -- Siehe beispielsweise in die Klasse CamAndroid der Library ComposingForEveryone

    public void step()
    {
        int count = 0;
        for(int i=0;i<pix.length;i++)
        {
                int c = pixsource[i];
                int RED   = c >> 16 & 0xFF;
                int GREEN = c >> 8 & 0xFF;
                int BLUE  = c & 0xFF;
                
                int REDCOMP = 2*RED - GREEN - BLUE;                                
                int GREENCOMP = 2*GREEN - RED - BLUE;                                
                int BLUECOMP = 2*BLUE - RED - GREEN;                                
                int YELLOWCOMP = RED+GREEN - 2*BLUE;                
                
                int RC = REDCOMP;
                int GC = GREENCOMP;
                int BC = BLUECOMP;
                
                if(RC<0) RC=0;
                if(RC>255) RC=255;
                if(GC<0) GC=0;
                if(GC>255) GC=255;
                if(BC<0) BC=0;
                if(BC>255) BC=255;
                
                int GREYCOMP = (RC+GC+BC)/3;                                
                
                if(GREYCOMP<threshold)     
                {
                    pix[i]=0;
                    
                    count++;
                }
                else
                {
                    if(YELLOWCOMP>BLUECOMP+YOFF && YELLOWCOMP>GREENCOMP+YOFF && YELLOWCOMP>REDCOMP+YOFF)
                    {
                        pix[i] = 4;
                    }    
                    else if(BLUECOMP>YELLOWCOMP+BOFF && BLUECOMP>GREENCOMP+BOFF && BLUECOMP>REDCOMP+BOFF)
                    {
                        pix[i] = 3;
                    }    
                    else if(GREENCOMP>YELLOWCOMP+GOFF && GREENCOMP>BLUECOMP+GOFF && GREENCOMP>REDCOMP+GOFF)
                    {
                        pix[i] = 2;
                    }    
                    else if(REDCOMP>YELLOWCOMP+ROFF && REDCOMP>BLUECOMP+ROFF && REDCOMP>GREENCOMP+ROFF)
                    {
                        pix[i] = 1;
                    }    
                    else
                    {
                        pix[i] = 0;
                        count++;
                    }
                }
        }
        if(successor!=null)
            successor.step();           
    }

Code 0-3: pixel in Farbanteile umwandeln -- Siehe beispielsweise in die Klasse RGBY der Library ComposingForEveryone

//Selber Exceptions schreiben:

public class LeereDateiException extends RuntimeException
{
     public LeereDateiException() 
     {
          super("Datei ist leer!");
     }     
}
String[] data;
public void laden() throws LeereDateiException
{
     data = loadStrings("test.txt");
     if(data==null || data.length==0)
        throw new LeereDateiException();
}

public void setup()
{
  try
  {
       laden();
  }
  catch(Exception e)
  {
    println(e.toString());
  }
  
}

Code 0-4: Kleines Beispiel

//Selber Exceptions schreiben:
int i=0;
public class zuweitLinks extends RuntimeException
{
    public zuweitLinks()
    {
        super("Maus zu weit links!");
    }
}
String[] data;
public void laden() throws zuweitLinks
{
    line(mouseX, 20, mouseX, 80);
    if(mouseX<width/2)
         throw new zuweitLinks();
}

public void setup()
{
    size(1000,1000);
}
int ROT = 0;
public void draw()
{
    ROT = 0;
    try
    {
        laden();
    }
    catch(Exception e)
    {
       i++;
       println(e.toString());
       println(i);
       ROT = 255;
    }
    background(ROT, 30, 30);
}

Code 0-5: Studentische Lösung.

S001 Someone in Charge -> Verantwortlicher bekommt eine Meldung per Exception 
                          und kümmert sich um den Fehler z.B.
                          "schiebt Maus in richtige Position"

S002 Minimize human interaction -> Möglich: Fehler wird durch Maschine behoben,
                                   statt durch Menschen, wenn Exception auftritt.

S003 Escalation -> if  else if  else if else -Struktur oder 
                   ineinander geschachtelte Exceptions

S004 Recovery-Blocks -> Exception... um Modul zu testen und zu reagieren,
                        also hier ein alternatives Modul zu verwenden.
                        Schnittstellen, um die Module zusammenzufassen 

S005 Software-Update -> 1. Mögl.: Redundanz, ein System herunterfahren und Code
                           austauschen.
                        2. Skriptsprache verwenden, hier Code-Tausch
                           on-the-fly möglich.
                        3. Klassen in Java austauschen und von der virtual Machine
                           neu laden lassen.

S006 Fault Observer -> Fehler erkennen und weiterleiten, Exception wichtiges Element dafür
                       Konzept-Beispiel: Berichterstatter-Klasse, von der alle
                       Exception-Klassen erben.

S007 Maximize human participation -> Informationen zum Systemzusatnd auf Bildschirm
                                     beispielsweise

S008 Correcting Audits -> static   .. 
                        / dynamic  ..

Code 0-6: Anwendbarkeit von Exception oder Schnittstellen zur Implementierung der Pattern.

//PC seitig
import oscP5.*;
import netP5.*;

OscP5 oscP5;
NetAddress myRemoteLocation;
int hell=0;
int hellandroid=0;
public void setup()
{
  size(400,400);
  frameRate(25);
  /* start oscP5, listening for incoming messages at port 12000 */
  oscP5 = new OscP5(this,12000);
  
  /* myRemoteLocation is a NetAddress. a NetAddress takes 2 parameters,
   * an ip address and a port number. myRemoteLocation is used as parameter in
   * oscP5.send() when sending osc packets to another computer, device, 
   * application. usage see below. for testing purposes the listening port
   * and the port of the remote location address are the same, hence you will
   * send messages back to this sketch.
   */  
  myRemoteLocation = new NetAddress("192.168.252.255",12000); //senden an Broadcast-Adresse meines Hotspots!
  
}

public void draw()
{
     fill(hell);
     noStroke();
     rect(0,0,width/2,height);
     fill(hellandroid);
     noStroke();
     rect(width/2,0,width/2,height);
     
     fill(255,0,0);
     stroke(255,0,0);
     strokeWeight(height/150);
     line(width/2,0,width/2,height);
     textSize(32);
     text("PC",50,50);
     text("ANDROID",width/2+50,50);
}


public void mouseDragged()
{
      hell = (int)(255.0*mouseY/height);
      OscMessage myMessage = new OscMessage("/hellpc");  
      myMessage.add(hell); /* add an int to the osc message */
      oscP5.send(myMessage, myRemoteLocation);       
}

/* incoming osc message are forwarded to the oscEvent method. */
void oscEvent(OscMessage theOscMessage) 
{
  /* print the address pattern and the typetag of the received OscMessage */
  print("### received an osc message.");
  print(" addrpattern: "+theOscMessage.addrPattern());
  println(" typetag: "+theOscMessage.typetag());
  if(theOscMessage.checkAddrPattern("/hellandroid")==true) 
  {
       hellandroid = theOscMessage.get(0).intValue();
  }
}

Code 0-7: IOT001pc -- PC-seitiges Programm. Sendet Helligkeitswert an Broadcast-Adresse unter dem Namen "hellpc" und empfängt als Rückmeldung "hellandroid".

//ANDROID seitig
import oscP5.*;
import netP5.*;

OscP5 oscP5;
NetAddress myRemoteLocation;
int hell=0;
int hellalt=0;
public void setup()
{
  fullScreen();
  orientation(LANDSCAPE);
  frameRate(25);
  /* start oscP5, listening for incoming messages at port 12000 */
  oscP5 = new OscP5(this,12000);
  
  /* myRemoteLocation is a NetAddress. a NetAddress takes 2 parameters,
   * an ip address and a port number. myRemoteLocation is used as parameter in
   * oscP5.send() when sending osc packets to another computer, device, 
   * application. usage see below. for testing purposes the listening port
   * and the port of the remote location address are the same, hence you will
   * send messages back to this sketch.
   */  
  myRemoteLocation = new NetAddress("192.168.252.255",12000); //senden an Broadcast-Adresse meines Hotspots!
  
}

public void draw()
{
     fill(hell);
     noStroke();
     rect(0,0,width/2,height);
     
     if(hell!=hellalt)
     {
          //testweise Wert zurück senden
          hellalt = hell;
          OscMessage myMessage = new OscMessage("/hellandroid");  
          myMessage.add(hell); /* add an int to the osc message */
          oscP5.send(myMessage, myRemoteLocation);       
          
     }
}



/* incoming osc message are forwarded to the oscEvent method. */
void oscEvent(OscMessage theOscMessage) 
{
  /* print the address pattern and the typetag of the received OscMessage */
  print("### received an osc message ANDROID.");
  print(" addrpattern ANDROID: "+theOscMessage.addrPattern());
  println(" typetag ANDROID: "+theOscMessage.typetag());
  if(theOscMessage.checkAddrPattern("/hellpc")==true) 
  {
       hell = theOscMessage.get(0).intValue();
  }
}

Code 0-8: IOT001android -- Android-seitiges Programm. Empfängt "hellpc" und sendet "hellandroid" zur Kontrolle zurück.

//PC seitig
import oscP5.*;
import netP5.*;

OscP5 oscP5;
NetAddress myRemoteLocation;
int hell=0;
int hellandroid=0;
float phi;
public void setup()
{
  size(400,400);
  frameRate(25);
  /* start oscP5, listening for incoming messages at port 12000 */
  oscP5 = new OscP5(this,12000);
  
  /* myRemoteLocation is a NetAddress. a NetAddress takes 2 parameters,
   * an ip address and a port number. myRemoteLocation is used as parameter in
   * oscP5.send() when sending osc packets to another computer, device, 
   * application. usage see below. for testing purposes the listening port
   * and the port of the remote location address are the same, hence you will
   * send messages back to this sketch.
   */  
  myRemoteLocation = new NetAddress("192.168.252.255",12000); //senden an Broadcast-Adresse meines Hotspots!
    
}

public void draw()
{
     fill(hell);
     noStroke();
     rect(0,0,width/2,height);
     fill(hellandroid);
     noStroke();
     rect(width/2,0,width/2,height);
     
     fill(255,0,0);
     stroke(255,0,0);
     strokeWeight(height/150);
     line(width/2,0,width/2,height);
     textSize(32);
     text("PC",50,50);
     text("ANDROID",width/2+50,50);
     text("phi="+(180.0*phi/PI),width/2+10,150);
}


public void mouseDragged()
{
      hell = (int)(255.0*mouseY/height);
      OscMessage myMessage = new OscMessage("/hellpc");  
      myMessage.add(hell); /* add an int to the osc message */
      oscP5.send(myMessage, myRemoteLocation);       
}

/* incoming osc message are forwarded to the oscEvent method. */
void oscEvent(OscMessage theOscMessage) 
{
  /* print the address pattern and the typetag of the received OscMessage */
  print("### received an osc message.");
  print(" addrpattern: "+theOscMessage.addrPattern());
  println(" typetag: "+theOscMessage.typetag());
  if(theOscMessage.checkAddrPattern("/hellandroid")==true) 
  {
       hellandroid = theOscMessage.get(0).intValue();
  }
  if(theOscMessage.checkAddrPattern("/phiandroid")==true) 
  {
       int PHI = theOscMessage.get(0).intValue();
       phi = (float)PHI/100.0;
  }
}

Code 0-9: PC-seitige Erweiterung

//ANDROID seitig
import oscP5.*;
import netP5.*;
import ketai.sensors.*;

OscP5 oscP5;
NetAddress myRemoteLocation;
int hell=0;
int hellalt=0;

int PHI=0;

KetaiSensor sensor;
float accelerometerX, accelerometerY, accelerometerZ;

public void setup()
{
  sensor = new KetaiSensor(this);
  sensor.start();
  
  fullScreen();
  orientation(LANDSCAPE);
  frameRate(25);
  /* start oscP5, listening for incoming messages at port 12000 */
  oscP5 = new OscP5(this,12000);
  
  /* myRemoteLocation is a NetAddress. a NetAddress takes 2 parameters,
   * an ip address and a port number. myRemoteLocation is used as parameter in
   * oscP5.send() when sending osc packets to another computer, device, 
   * application. usage see below. for testing purposes the listening port
   * and the port of the remote location address are the same, hence you will
   * send messages back to this sketch.
   */  
  myRemoteLocation = new NetAddress("192.168.252.255",12000); //senden an Broadcast-Adresse meines Hotspots!
  
}



public void draw()
{
     fill(hell);
     noStroke();
     rect(0,0,width/2,height);
     
     if(hell!=hellalt)
     {
          //testweise Wert zurück senden
          hellalt = hell;
          OscMessage myMessage = new OscMessage("/hellandroid");  
          myMessage.add(hell); /* add an int to the osc message */
          oscP5.send(myMessage, myRemoteLocation);       
          
     }
}



/* incoming osc message are forwarded to the oscEvent method. */
void oscEvent(OscMessage theOscMessage) 
{
  /* print the address pattern and the typetag of the received OscMessage */
  print("### received an osc message ANDROID.");
  print(" addrpattern ANDROID: "+theOscMessage.addrPattern());
  println(" typetag ANDROID: "+theOscMessage.typetag());
  if(theOscMessage.checkAddrPattern("/hellpc")==true) 
  {
       hell = theOscMessage.get(0).intValue();
  }
}

void onAccelerometerEvent(float x, float y, float z)
{
  accelerometerX = x;
  accelerometerY = y;
  accelerometerZ = z;
  
  //    Drehung in xy-Ebene:
  //    cos phi = v1*v2 / (|v1|*|v2|)
  //    v1 = [x,y]
  //    v2 = [1,0]
  
  float[] v1 = new float[] {x,y};
  float[] v2 = new float[] {1,0};
  
  float betragV1 = sqrt(v1[0]*v1[0]+v1[1]*v1[1]);
  float betragV2 = sqrt(v2[0]*v2[0]+v2[1]*v2[1]);
  
  float phi = acos( x / (betragV1*betragV2)  );
  if(y<0)
    phi = -phi;
    
  PHI = (int)(phi*100.5);  
    
  OscMessage myMessage = new OscMessage("/phiandroid");  
  myMessage.add(PHI); /* add an int to the osc message */
  oscP5.send(myMessage, myRemoteLocation);       
    
}

Code 0-10: Android-seitige Erweiterung