void setup() 
{
  pinMode(2,INPUT);  
//  digitalWrite(2,1); //Pullup-Widerstand
  digitalWrite(2,0); //Deaktivieren von Pullup-Widerstand
  //d.h. Es muß extern ein Pulldown-Widerstand verbunden werden.
  pinMode(4, OUTPUT); 
  pinMode(6, OUTPUT);   
}

void loop() 
{
  if(digitalRead(2)==HIGH)
  {
      digitalWrite(4,1);
      digitalWrite(6,1);    
  }
  else
  {
      digitalWrite(4,0);
      digitalWrite(6,0);    
  }  
}

Code 0-1: 2. Externe Pulldown-Widerstände statt interne Pullup-Widerstände.

//Hier sehen wir:
//http://www.kramann.info/45_Mikro17/02_ArduinoMicro/index.php

//D2 entspricht PD1
//D4 entspricht PD4
//D6 entspricht PD7

//Wir ersetzen jetzt jeden Arduino-Befehl durch den passenden
//Registerbefehl:

void setup() 
{
//  pinMode(2,INPUT);  
//  DDRD &= 0b11111101;
  DDRD &= ~(1<<PD1);
  
//  digitalWrite(2,0); //Deaktivieren von Pullup-Widerstand
  PORTD &= 0b11111101;
  
  //d.h. Es muß extern ein Pulldown-Widerstand verbunden werden.
//  pinMode(4, OUTPUT); 
  DDRD |= 0b00010000;
//  pinMode(6, OUTPUT);   
  DDRD |= 0b10000000;
}

void loop() 
{
  
//  if(digitalRead(2)==HIGH)
//  if(  (PIND & 0b00000010) == 2 )
  if(  (PIND & (1<<PD1)) == (1<<PD1) )
  {
      //digitalWrite(4,1);
      PORTD |= (1<<PD4);
      //digitalWrite(6,1);    
      PORTD |= (1<<PD7);
  }
  else
  {
      //digitalWrite(4,0);
      PORTD &= ~(1<<PD4);
      //digitalWrite(6,0);    
      PORTD &= ~(1<<PD7);
  }  
}

Code 0-2: 3. Gleiches Programm wie 2., aber mit Registerbefehlen realisiert (Korrespondierende Arduino-Befehle jeweils darüber als Kommentar).

fpwm = 100Hz
TOP = 10000
N = 8

//       MODE8                     VORTEILUNG N=8 Seite 133
TCCR1B = (1<<WGM13) | (0<<WGM12) | (0<<CS12) | (1<<CS11) | (0<<CS10);
TCCR1A = (0<<WGM11) | (0<<WGM10) | (1<<COM1A1) | (0<<COM1A0);
ICR1   = 10000; //TOP für PWM MODE 8
DDRB = (1<<PB5);
OCR1A = ...

Code 0-3: Daten für die Servo-Ansteuerung aus der Vorlesung.

int pos = 0;

void setup() 
{
    TCCR1B = (1<<WGM13) | (0<<WGM12) | (0<<CS12) | (1<<CS11) | (0<<CS10);
    TCCR1A = (0<<WGM11) | (0<<WGM10) | (1<<COM1A1) | (0<<COM1A0);
       
    ICR1 = 10000;//TOP für PWM MODE 8
    DDRB = (1<<PB5);

    OCR1A = 0;
    OCR1B = 1500;
}

void loop() 
{
    for(pos = 500; pos <= 2500; pos+=60){
      OCR1A = pos;  
      delay(15);
    }
    
    for(pos = 2500; pos >= 500; pos-=60){
      OCR1A = pos;
      delay(15);  
    }
}

Code 0-4: Studentische Lösung zur Register-basierten Ansteuerung eines Servos.

//Festlegen eines Typs von Lauflicht der realisiert wird.
//z.B. Mode0 == Alle LEDs leuchten gemeinsam auf und gehen im nächsten Zeitschritt wieder aus.
//z.B. Mode1 == Lauflicht: Das Licht wandert von LED zu LED und beginnt dann wieder von vorne.
//z.B. Mode2 == Zylon: Das Licht wandert hin und her.
void setMode(int m)
{
   ...
}

//Bei dem Aufruf von Timestep wird der nächste Zustand von Lauflicht umgesetzt,
//egal in welchem Modus sich Lauflicht befindet.
void timestep()
{
    ...
}

Code 0-5: Methoden der Klasse Lauflicht.

void setup() 
{
  TCCR1B &= ~(1<<WGM13); //Mode 4
  TCCR1B |= (1<<WGM12);
  TCCR1A &= ~(1<<WGM11);
  TCCR1A &= ~(1<<WGM10);
    
  //Vorteilung 1: 16000000Hz
  TCCR1B &= ~(1<<CS12);
  TCCR1B &= ~(1<<CS11);
  TCCR1B |= (1<<CS10);
    
  //f = fclk/(2*N*(OCR1A+1))
  //OCR1A = (fclk/(f*2*N))-1
  //OCR1A = 8000000/440 - 1 ==  18181
  OCR1A=18181;  //0,5Hz == 4 Schläge!
  
  //Toggle auf OC1A:
  TCCR1A &= ~(1<<COM1A1);
  TCCR1A |=  (1<<COM1A0);
  pinMode(9,OUTPUT);    
}

void loop() 
{       
}

Code 0-6: CTC-Mode mit Arduino. Beispiel.

void setup() 
{
//   ICR1 = fclk / (fctc*2*N)    - 1 
//   ICR1 = 16000000 / (1000*2*64) - 1 = 124
  
    TCCR1B = (0<<WGM13) | (1<<WGM12) | (0<<CS12) | (1<<CS11) | (1<<CS10);
    TCCR1A = (0<<WGM11) | (0<<WGM10) | (0<<COM1A1) | (1<<COM1A0);
    //ICR1 = 124;//TOP CTC MODE 12 (hat nicht funktioniert)
    OCR1A=124; // statt dessen Mode 4
    DDRB |= (1<<PB5);
}

void loop()
{
}

Code 0-7: Lauffähiger Code für ein 1kHz Signal.

#include<avr/interrupt.h>
volatile bool AN=false;
volatile bool ZUSTAND=false;
ISR(TIMER1_COMPA_vect)
{
    if(ZUSTAND)
        digitalWrite(12,ZUSTAND);
    else        
        digitalWrite(12,ZUSTAND);
        
    ZUSTAND=!ZUSTAND;        
}

void setup() 
{
  TCCR1B &= ~(1<<WGM13); //Mode 4
  TCCR1B |= (1<<WGM12);
  TCCR1A &= ~(1<<WGM11);
  TCCR1A &= ~(1<<WGM10);
    
  //1024: 15625Hz
  TCCR1B |= (1<<CS12);
  TCCR1B &= ~(1<<CS11);
  TCCR1B |= (1<<CS10);
    
  OCR1A=31250;  //0,5Hz == 4 Schläge!
  
  TIMSK1 |= (1<<OCIE1A); //Mode 4
  sei();  
  pinMode(12,OUTPUT);
}

void loop() 
{
}

Code 0-8: interrupt - Sketch aus der Vorlesung

#include<avr/interrupt.h>

bool wort[] = {1,1,1,0,1,0,0,0,0,0,1,0,1,1,1,1};
int inx = 0;
ISR(TIMER1_COMPA_vect)
{   
     digitalWrite(13,wort[inx]);   
     inx++;
     inx%=16;
}


void setup() 
{
    TCCR1B &= ~(1<<WGM13); //Mode 4
    TCCR1B |= (1<<WGM12);
    TCCR1A &= ~(1<<WGM11);
    TCCR1A &= ~(1<<WGM10);
    
    //1024: 15625Hz
    //1: 16000000Hz
    TCCR1B &= ~(1<<CS12);
    TCCR1B &= ~(1<<CS11);
    TCCR1B |= (1<<CS10);
    
    OCR1A=1667;  //16000000Hz == 1 => 9600Hz == 1667
  
    TIMSK1 |= (1<<OCIE1A); //Mode 4
    sei();    

    Serial.begin(9600);
    Serial1.begin(9600);

    pinMode(13,OUTPUT);
    digitalWrite(13,HIGH);
}

void loop() 
{
    if(Serial1.available()) 
    {
        Serial.write(Serial1.read());
    }
}

Code 0-9: Serialemu001, senden

#include<avr/interrupt.h>
#define LESEPIN 13
#define PUFFERGROESSE 100
//Serielle Daten über die emulierte Schnittstelle empfangen!
int leseindex = 0;
bool liestgerade = false;
int  zeichen;
char inpuffer[PUFFERGROESSE];
int inindex = 0;
int inindey = 0;

int x=0;
int zaehler=0;
ISR(TIMER1_COMPA_vect)
{   
    if(liestgerade==false && digitalRead(LESEPIN)==LOW)
    {
        leseindex = 0;
        zeichen = 0;
        liestgerade = true;
    }
    if(liestgerade==true)
    {
        if(leseindex==12 && digitalRead(LESEPIN)==HIGH) zeichen+=1;
        if(leseindex==12+8 && digitalRead(LESEPIN)==HIGH) zeichen+=2;
        if(leseindex==12+16 && digitalRead(LESEPIN)==HIGH) zeichen+=4;
        if(leseindex==12+24 && digitalRead(LESEPIN)==HIGH) zeichen+=8;
        if(leseindex==12+32 && digitalRead(LESEPIN)==HIGH) zeichen+=16;
        if(leseindex==12+40 && digitalRead(LESEPIN)==HIGH) zeichen+=32;
        if(leseindex==12+48 && digitalRead(LESEPIN)==HIGH) zeichen+=64;
        if(leseindex==12+56 && digitalRead(LESEPIN)==HIGH) zeichen+=128;

        if(leseindex>=12+64)
        {
            liestgerade=false;
            inpuffer[inindex] = zeichen;
            inindex++;
            inindex%=PUFFERGROESSE;
        }        
        leseindex++;      
    }
}


void setup() 
{
    TCCR1B &= ~(1<<WGM13); //Mode 4
    TCCR1B |= (1<<WGM12);
    TCCR1A &= ~(1<<WGM11);
    TCCR1A &= ~(1<<WGM10);
    
    //1024: 15625Hz
    //1: 16000000Hz
    TCCR1B &= ~(1<<CS12);
    TCCR1B &= ~(1<<CS11);
    TCCR1B |= (1<<CS10);
    
//8fach:    
//    OCR1A=208;  //16000000Hz == 1 => 8*9600Hz == 208,3333
//Glatte Teiler:
    OCR1A=250;  //16000000Hz == 1 => 8*8000Hz == 250

//    OCR1A=1667;  //16000000Hz == 1 => 9600Hz == 1667
  
    TIMSK1 |= (1<<OCIE1A); //Mode 4
    sei();    


    pinMode(LESEPIN,INPUT);
    digitalWrite(LESEPIN,HIGH); //macht Sinn, um ohne Verbindung High-Potential zu gewährleisten
    Serial1.begin(8000);
    Serial.begin(8000);
}

void loop() 
{
    if(zaehler>10000)
    {
       Serial1.write('A'+x);
       x++;
       x%=10;
       zaehler=0;
    }
    //delay(100);

    if(inindex != inindey)
    {
        Serial.write(inpuffer[inindey]);
        inindey++;
        inindey%=PUFFERGROESSE;
    }

    zaehler++;
}

Code 0-10: Serialemu002c, empfangen