kramann.info

3.1.11 Bestimmung weiterer Parameter mittels der Methode der kleinsten Quadrate

Verarbeitung Rohdaten3: k aus Dynamoeffekt

In dem Versuch wurde ein baugleicher Motor als Dynamo an den andern angekoppelt.
So konnte die induzierte Spannung e in Abhängigkeit der Winkelgeschwindigkeit ω gemessen werden.
Aus dieser Reihe und der reduzierten elektrischen Modellgleichung kann über LSQ k bestimmt werden.
Reduktion der Modellgleichung:

Bild 3.1.11-1: Reduzierte Modellgleichung, Umformung für LSQ.

Zur Auswertung wird das folgende Scilab-Programm verwendet:

//Matrix mit Meßdaten laden:
M=fscanfMat("induziert.txt")

//Dimensionen feststellen:
[zeilen,spalten] = size(M)


//Konstante PI merken:
PI = 3.1415926535897932384626433832795

//Matrix B erzeugen (hier wird nur die Spalte mit Omega zur Bestimmung von k verwendet):
//1. Spalte von M mal 2pi/12 wird zweite von B
B = [M(:,1).*(2.0*PI/12.0)]

//Matrix d sind die negativen Werte der Spannung U, also die zweite Spalte von M,
d = M(:,2).*(-1.0)

//Bestimmung von k:
c = lsq(B,-d)

//liefert hier:
//k = 0.0164873

Code 3.1.11-1: Scilab-Programm zur Bestimmung von k mittels der Methode der kleinsten Quadrate aus induzierter Spannung e.

Download der Meßdaten und des obigen Scilab-Skripts

Verarbeitung Rohdaten5: Bestimmung von k_m und H aus dem statischen Moment

In diesem Versuch wurde die auf eine Waage durch den Motor über einen Hebelarm aufgebrachte Kraft gemessen und der Motorstrom.
Zusammen mit der mechanischen Modellgleichung und ω=0rad/s kann man daraus k_m bestimmen:

Bild 3.1.11-3: Reduzierte mechanische Modellgleichung, Umformung für LSQ.

Wir betrachten hier das abgegebene Moment M.
Es wird reduziert um die Haftreibung.
Unbekannte sind für LSQ die Parameter k_m und H.
Mit M=F*Hebelarm ergibt sich folgendes Scilab-Skript zur Bestimmung von k_m und G:

Download der Meßdaten und des obigen Scilab-Skripts.

//Vorbereitung: mit cd <Pfad> in das Verzeichnis gehen, wo sich die Meßdaten befinden

//Matrix mit Meßdaten laden:
M=fscanfMat("moment.txt")

//Dimensionen feststellen:
[zeilen,spalten] = size(M)


//Konstante PI merken:
PI = 3.1415926535897932384626433832795

//Matrix B erzeugen:
//Bc+d = r <=>
//k*i-H*1-M = 0
//2. Spalte von M mal 0.001 wird erste von B
//Ein Vektor mit minus Einsern wird zweite von B
B = [M(:,2).*0.001,-1.*ones(zeilen,1)]

//Das Moment ergibt sich aus dem Produkt mit der gemessenen Kraft mit dem Hebelarm:
//M = m*g*l, l=0,0456m, g=9,91m/s2, m: mit der Waage gemessenes Gewicht in kg (Faktor 0,001)
d = M(:,3).*(-0.001*0.0456*9.81)

//Bestimmung von k und R:
//Scilab bietet schon die Kleinste Quadrate-Methode als Funktion an, der man einfach B und -d übergibt.
//Hier muß man anders, als wenn man es von Hand macht nicht d, sondern -d übergeben:
c = lsq(B,-d)

//liefert hier:
//km = 0.0176638
//H  = 0.0003937

Code 3.1.11-1: Scilab-Programm zur Bestimmung von k_m und G mittels der Methode der kleinsten Quadrate aus dem statischen Moment M.

U/V	I/mA	Gewicht/gramm	Moment/Nm
2.0	106.5	3.6		0.0016104
3.0	157.8	5.4		0.0024156
4.0	206.4	7.1		0.0031761
5.0	253.0	8.9		0.0039813
6.0	293.4	10.5		0.0046970
7.0	315.0	11.6		0.0051891
8.0	390.0	14.6		0.0065311
9.0	410.0	15.1		0.0067548
10.0	440.0	16.7		0.0074705
11.0	460.0	17.6		0.0078731
12.0	480.0	17.9		0.0080073

Code 3.1.11-2: Statisches Moment gegen Strom und Spannung aufgetragen.

Verarbeitung Rohdaten2: Bestimmung von G und D mit Hilfe des mechanischen Modells

//Vorbereitung: mit cd  in das Verzeichnis gehen, wo sich die Meßdaten befinden

//Matrix mit Meßdaten laden:
M=fscanfMat("stationaer2.txt")

//Dimensionen feststellen:
[zeilen,spalten] = size(M)


//Konstante PI merken:
PI = 3.1415926535897932384626433832795

//Mechanisches Modell:
//J dw/dt = kmi -Dw -Gsign(w)
//stationaer:
// 0 = kmi - Dw - G
//für LSQ:
// D*w + G*1 - km*i = 0

//Matrix B erzeugen:
//3. Spalte von M mal 2pi/12 wird erste von B
//Nur Einser wird zweite von B
B = [M(:,3).*(2.0*PI/12.0),ones(zeilen,1)]

//Matrix d sind die negativen Werte der Spannung U, also die erste Spalte von M:
//km wird mit km=0,0078 veranschlagt (s. alternative Bestimmungen)
d = M(:,2).*(-0.001).*0.0078

//Bestimmung von D und G:
c = lsq(B,-d)

//liefert hier:
//D = 0,0000002 Nms
//G = 0,0001964 Nm

//Varianten:

Code 3.1.11-3: Scilab-Programm zur Bestimmung von G und D

Verarbeitung Rohdaten4: Motor-Effektivität aus Messung der Leistungsübertragung "Rohdaten 4"

Bei dem Elektromotor wird nicht die gesamte elektrische Leistung in mechanische umgewandelt.
Der Hersteller gibt eine Effektivität von 47% an.
Diese soll hier nachgemessen werden und mit ihr läßt sich auch ggf. ein Unterschied zwischen k und k_m bestimmen.
Es gelten folgende Zusammenhänge zwischen den Leistungsgrößen:

Elektrische Leistung: P_el=e*i=k*ω*i, also die induzierte Spannung mal dem fließenden Strom.
Die elektrische Leistung wird von dem Motor aufgenommen.
Mechanische Leistung: P_m=M*ω=k_m*i*ω, also die gegen ein Moment aufgebrachte Winkelgeschwindigkeit (analog Translation: P=F*v).
Hier wurde zunächst die Reibung vernachlässigt.
Nimmt man sie noch hinzu, ergibt sich:
Mechanische Leistung samt Reibleistung: P_mr=(k_m*i-D*ω-G*sign(ω))*ω.

Für den Übergang zwischen elektrischer und mechanischer Leistung beim ersten Motor gilt: P_mr1 = q*P_el1.
q ist dabei die Effektivität.
Für den Übergang zwischen mechanischer und elektrischer Leistung beim zweiten Motor gilt: P_el2 = q*P_mr2.
Da beide Motoren gekoppelt sind, gilt:
P_mr1 = P_mr2 und somit auch:
P_el2 = q²*P_el1.
Somit läßt sich mit Hilfe der Versuchsanordnung in "Rohdaten 4" die Effektivität q bestimmen.
Aufbereitung für die Anwendung von LSQ:
P_el2/P_el1-QQ=0
Mit QQ = q²
Das folgende Scilab-Skript bestimmt die Effektivität q:

//Matrix mit Meßdaten laden:
M=fscanfMat("leistung.txt")

//Dimensionen feststellen:
[zeilen,spalten] = size(M)


//Konstante PI merken:
PI = 3.1415926535897932384626433832795

//Form Bc+d=0 erzeugen.
//Vektor d erzeugen.
//Nur eine Spalte, die Pel2/Pel1 enthält == (U2*I2)/(U1*I1)
//(in Volt und Apere umrechnen)
d = [ -1.0.*(M(:,4).*M(:,5).*0.001.*0.001)./(M(:,1).*M(:,2).*0.001) ]

//Matrix B stehen lauter Einser (Faktor vor QQ=q^2)
B = ones(zeilen,1)

//Bestimmung von k:
c = lsq(B,-d)

//liefert hier:
//QQ = q^2 = 0.0164873

q = sqrt(c)

//ist aber nicht brauchbar, da q nicht konstant:
qverlauf = sqrt(-d);
plot(M(:,3).*(PI/6.0),qverlauf)

Code 3.1.11-2: Scilab-Programm zur Bestimmung der Effektivität q.

Der folgende Plot zeigt aber, dass die Effektivität alles andere als konstant ist.
Somit ist der berechnete Wert für q nicht benutzbar.

Bild 3.1.11-3: Effektivität gegen die Winkelgeschwindigkeit aufgetragen.

    w/rad        Effektivität
    26.179939    0.0613446
    60.737458    0.125499
    96.865773    0.1565597
    129.3289     0.1712727
    160.74482    0.1823264
    188.49556    0.1842126
    220.95868    0.1878962
    259.18139    0.1963719
    297.9277     0.2059823
    333.00882    0.2099462
    370.70793    0.2134285

Code 3.1.11-3: Effektivität q in Abhängigkeit der Winkelgeschwindigkeit.

3.1.11 Bestimmung weiterer Parameter mittels der Methode der kleinsten Quadrate

Verarbeitung Rohdaten3: k aus Dynamoeffekt

Verarbeitung Rohdaten5: Bestimmung von km und H aus dem statischen Moment

Verarbeitung Rohdaten2: Bestimmung von G und D mit Hilfe des mechanischen Modells

Verarbeitung Rohdaten4: Motor-Effektivität aus Messung der Leistungsübertragung "Rohdaten 4"

Verarbeitung Rohdaten5: Bestimmung von k_m und H aus dem statischen Moment