kramann.info
© Guido Kramann

Login: Passwort:










11.4 Verwendung des Bode-Diagramms zur Beurteilung linearer Regelkreise

11.4 (EN google-translate)

11.4 (PL google-translate)

  • Das Bode-Diagramm besteht aus zwei übereinander angeordneten Teildiagrammen.
  • In dem ersten wird der Betrag A(iω) der Ortskurve dargestellt, im zweiten die Phase φ(iω).
  • Für die Kreisfrequenz (Ordinate) wird eine logarithmusche Darstellung gewählt.
  • Der Betrag wird in Dezibel dargestellt.
Formeln

Bild 11.4-1: Formeln

Vereinfachtes Nyquist-Kriterium

  • Der geschlossene Regelkreis eines linearen Systems ist asymptotisch stabil, wenn folgende Kriterien erfüllt sind:
  1. Der offene Regelkreis hat nur Eigenwerte in der linken Halbebene oder maximal zwei Eigenwerte direkt im Ursprung.
  2. Der Amplitudengang des offenen Regelkreises schneidet die Null-Dezibel-Linie genau einmal an der Stelle ωD - DURCHTRITTSFREQUENZ.
  3. An der Stelle ωD ist der Winkel im Phasendiagramm φ(ωD) größer als -180o.
//s als Argument für ein Polynom definieren:
s = poly(0,"s"); 
//Parameter festlegen:
K = 10; 
T = 1; 
P = 1; 
//Übertragungsfunktion definieren:
G = syslin('c',[K],[1+s*T+P*s^2]); //PT2
R = syslin('c',[s+1],[1]);
//GR = syslin('c',[K*(s+1)],[1+s*T+P*s^2]); //PT2+PD-Regler
GR = G*R;
//GRS = syslin('c',[K*(s+1)],[1+s*T+P*s^2+K*(s+1)]); //PT2+PD-Regler geschlossener Regelkreis
GRS = GR/(1+GR);

//Frequenzgang berechnen
freqmin=0.001; // minimale Frequenz
freqmax=10; // maximale Frequenz

bode(GR,freqmin,freqmax);

//Eigenwerte durch Umwandlung in State-Space-Form:
statespace1 = tf2ss(G);
A1 = statespace1(2);
B1 = statespace1(3);
C1 = statespace1(4);
D1 = statespace1(5);
spec(A1)

//Eigenwerte durch Umwandlung in State-Space-Form:
statespace2 = tf2ss(GR);
A2 = statespace2(2);
B2 = statespace2(3);
C2 = statespace2(4);
D2 = statespace2(5);
spec(A2)

//Eigenwerte durch Umwandlung in State-Space-Form:
statespace3 = tf2ss(GRS);
A3 = statespace3(2);
B3 = statespace3(3);
C3 = statespace3(4);
D3 = statespace3(5);
spec(A3)

Code 11.4-1: Scilab-Beispiel

Bodediagramm zum offenen Regelkreis.

Bild 11.4-2: Bodediagramm zum offenen Regelkreis.

Übung
  • Bestimmen Sie aus obigem Diagramm zum offenen Regelkreis die Durchtrittsfrequenz.
  • Ist der geschlossene Regelkreis zu obigem System asymptotisch stabil?
  • Vollziehen Sie Ihr Ergebnis von Hand nach.

Phasenreserve

Der Differenzwinkel, um den φ(ωD) größer als -180o ist, wird auch als Phasenreserve bezeichnet.

Amplitudenreserve

Man nimmt im Phasendiagramm die Stelle, an der φ=-180o ist, und schaut, wie weit dort der Wert im Amplitudendiagramm unterhalb der Null-Dezibel-Linie liegt.

Die Amplitudenreserve gibt Aufschluß darüber, um welchen Faktor die Regelstrecke noch verstärkt werden kann, ohne instabil zu werden.

Dämpfungsgrad

Für Systeme mit einem dominierenden konjugiert komplexen Eigenwertpaar gilt näherungsweise: Dämpfungsgrad=0.01*Phasenreserve.

Aufgaben (02.06.2014)
  • Linearisieren Sie das Modell für das invertierende Pendel um die (instabile) senkrechte Ruhelage herum.
  • Geben Sie das sich dabei ergebende Übertragungsverhalten an.
  • Legen Sie einen einfachen Regler für das linearisierte Modell unter Zuhilfenahme des vereinfachten Nyquist-Kriteriums aus.
  • Entwerfen und optimieren Sie einen Zustandsregler für das gleiche System.