kramann.info
© Guido Kramann

Login: Passwort:










7.1 Beschreibung eines Totzeitgliedes

  • Bei allen Meßvorgängen steht das Meßergebnis mit einer Zeitverzögerung gegenüber dem realen Verlauf zur Verfügung.
  • Insbesondere bei den immer häufiger verwendeten Mikrocontrollerschaltungen in Meßsystemen ist diese so genannte Totzeit Tt i.d.R. um Größenordnungen größer, als bei vergleichbaren diskret aufgebauten Schaltungen.
  • Direkt in Regelstrecken treten Totzeiten bei Transportvorgängen auf:
  • Bei einem Förderband für Schüttgut kommt die durch einen Schieber eingestellte Schütthöhe am Ende des Förderbandes zeitverzögert an.
  • Vergleichbares Verhalten hat man bei einer Zentralheizung. Da die Wärme mit durch lange Rohrleitungen fließendem Wasser an ihr Ziel transportiert wird, erfolgt auch hier eine Reaktion erst nach Ablauf einer festen Laufzeit.
  • Die Sprungantwort eines reinen Totzeitgliedes kommt mit Verstärkung 1 um die Zeit Tt verzögert am Ausgang an.
  • Im Zeitbereich läßt sich dies folgendermaßen darstellen:
Beschreibung eines Totzeitgliedes im Zeitbereich.

Bild 7.1-1: Beschreibung eines Totzeitgliedes im Zeitbereich.

  • Bei der Laplacetransformation ergibt sich:
Beschreibung eines Totzeitgliedes im Laplacebereich.

Bild 7.1-2: Beschreibung eines Totzeitgliedes im Laplacebereich.

  • Bei der Implementierung im Zeitbereich ist zu beachten, dass bis zu Tt in die Vergangenheit die Werte des Eingangssignals zwischengespeichert werden müssen, um sie zeitversetzt um die Totzeit zur Verfügung stellen zu können.

Simulation mit Totzeit mit Scilab

Da beim ODE-Integrator keine Möglichkeit vorhanden ist, Totzeit zu berücksichtigen, wird nachfolgend ersatzweise ein Runge-Kutta-Integrator implementiert und ein zeitverzögerter Ist-Wert xtot benutzt:

clear();

xtot=0;

function f=modell(y,t,dt)
       x=y(1,1);
       v=y(2,1);

       Kkrit = 2.25;       
       xsoll = 1.0;
       //e     = xsoll - x;
       e     = xsoll - xtot;
       u=Kkrit*e;
       
       f(1,1)=v;
       f(2,1)=-x-v+u;
endfunction

function yneu=ruku(y,t,dt)
       k1=modell(y,t,dt);
       k2=modell(y+0.5.*dt.*k1,t+0.5*dt);
       k3=modell(y+0.5.*dt.*k2,t+0.5*dt);
       k4=modell(y+dt.*k3,t+dt);
       yneu=y+dt.*(k1+2.*k2+2.*k3+k4)./6;
endfunction

tmax = 60.0;
dt   = 0.01;
schritte = ceil(tmax/dt);

yalt = [0,0]';
ysim = yalt;
t=0.0;
tt=t;

Ttot = 0.5;
anztot = round(Ttot/dt);
xtotarr = zeros(anztot);
xtotarr = zeros(50,1);

for i=1:1:schritte
    yneu=ruku(yalt,t,dt);   
    yalt=yneu;
    ysim=[ysim,yalt];
    tt  =[tt,t];
    t=t+dt;

    xtotarr(modulo((i-1),anztot)+1)=yneu(1);
    xtot = xtotarr(modulo((i-1+1),anztot)+1);
end

plot(tt,ysim(1,:))

Code 7.1-1: b003_kritisch_ruku.sce - Totzeit bei Scilab-Simulation zur Demonstration des kritischen Zustands.